Evaluate newer version of UltraEdit

[btking]

I have v9.xx installed and wanted to evaluate the latest release for the SFTP options. Can I install to a different directory without killing my current registered copy?

[Mofi]

Simply rename your existing UltraEdit directory and back up your uedit32.ini and uedit32.kbd before installation of the new version. I think, it is also possible to change the directory during installation, but it will always update the ini-file in the windows directory.

If you move all uedit32.* files from windows to UltraEdit directory and copy the whole UltraEdit directory with a new name in "Program Files" before installation of the new version, you can install the new version again to directory "UltraEdit" and later switch between the two versions easily by renaming the directories, when no UltraEdit instance is running.

Example:

Current installation directory: C:\Program Files\UltraEdit

Move C:\Windows\uedit32.* to C:\Program Files\UltraEdit

Before installation copied to: C:\Program Files\UltraEdit9

Install new version and let UE update existing V9.xx files in UltraEdit directory.

After installation:
New version in: C:\Program Files\UltraEdit
Old version in: C:\Program Files\UltraEdit9

To switch back to V9.xx:
rename UltraEdit to UltraEdit10
rename UltraEdit9 to UltraEdit

I personally use this method, because it has the advantage that all file associations will be the same, independent which version of UE I am using at the moment.

[palou]

Hi,

This is a bit out of subject, but why to put the ini file in the Windows directory instead of simply putting it in the application's one? It will be easer to live with multiple versions and everythings will be located in the same place.

[btking]

Thanks a million Mofi!!! Your suggestion works perfectly! Now maybe I can convince the boss to upgrade b/c the SFTP works very well for what I need to do...

[Bego]

Hi dudes, hi Mofi,

I actually test version 12 still having Version 11 installed as Mofi described above.
But fast, I got fed up with that f??? renaming stuff and decided to write a VB script for that.
Here it is, called switchUE.vbs

Just configure it and let it run. It explains itself.
Have fun. Oh, btw: NO GUARANTEE AT ALL !!!!

rds Bego

Code: Select all

'switchUE.vbs
'Switch between 2 (TWO!!!) UltraEdit installations
'PREREQUISITES:
'- Active folder is called like ...\UltraEdit
'- A second folders has to be named like ...\UltraEdit11   (with a SUFFIX as difference)
'- Make sure there are no UEdit* files in your Windows directory !
'
'Use the star (*) to look for configs YOU have to do :-)
'
Option Explicit
   Dim shl
   Dim exename
   Dim folderNewVersion   'check what is currently active + Plausicheck
   DIM folderOldVersion   'check what is currently active + Plausicheck

   Dim folderRunVersion
   Dim folderAktVersion
   Dim folderPasVersion
   Dim args
   Dim fso
   DIM AKTVERSION   'aktive Version
   DIM PASVERSION   'passive Version
   DIM OLDVERSION
   DIM NEWVERSION
   DIM SLASH
   DIM cntFolders
   dim answer

   OLDVERSION = "11"   '*
   NEWVERSION = "12"   '*
   folderRunVersion = "C:\Progra~1\Ultraedit"   '*
   folderNewVersion = folderRunVersion & NEWVERSION
   folderOldVersion = folderRunVersion & OLDVERSION
   exename = "uedit32.exe"
   SLASH = "\"
   cntFolders = 0

   '*** No more modification needed from here on ... ***
   Set fso = CreateObject("Scripting.FileSystemObject")

   cntFolders = abs(fso.FolderExists(folderRunVersion)) + _
             abs(fso.FolderExists(folderNewVersion)) + _
             abs(fso.FolderExists(folderOldVersion))

   'first, test the installation with its current configuration
   if cntFolders <> 2 then
      MeldungRaus ("Error. There are no 2 Ultraedit-Installations found. Found " & cntFolders)
   'else
   '   MeldungRaus ("Looks good. Found " & cntFolders)
   end if

   if fso.FolderExists(folderNewVersion) then
      AKTVERSION = OLDVERSION
      PASVERSION = NEWVERSION
   else
      AKTVERSION = NEWVERSION
      PASVERSION = OLDVERSION
   end if
   folderAktVersion = folderRunVersion & AKTVERSION
   folderPasVersion = folderRunVersion & PASVERSION
   answer = MsgBox("Active UE is version " & AKTVERSION & "." & vbcrlf & _
            "Should version " & PASVERSION & " be activated ?" & vbcrlf & vbcrlf & _
            "YES=activate and start" & vbcrlf & _
            "NO =just activate, no UE start" & vbcrlf & _
            "Cancel = do nothing" & vbcrlf _
            , vbQuestion+vbYesNoCancel, "Switch active UE-Version. CLOSE RUNNING UE's NOW !!!")
   if answer = vbcancel then
      wscript.quit
   end if
   'activate
   'msgbox  folderRunVersion & "-->" & folderAktVersion & vbcrlf & _
   '        folderPasVersion & "-->" & folderRunVersion
   fso.MoveFolder folderRunVersion, folderAktVersion
   fso.MoveFolder folderPasVersion, folderRunVersion
   if answer = vbyes then
      'Start UE
      Set shl = WScript.CreateObject("WScript.Shell")
      shl.Run folderRunVersion & SLASH & exename,1 ,FALSE
   end if

   wscript.quit

'----------------------------------------------------------------------------------

Sub MeldungRaus (strMeld)
   wscript.echo strMeld
   wscript.quit 1
End Sub